Tutorials
Articles
OpenGL Demos
Games
OpenGL Misc
MSG Board
About
Donate
Links
Home
Megabyte Softworks
C++, OpenGL, Algorithms




Current series: OpenGL 3.3
(Return to list of OpenGL 3.3 tutorials)

Download (2.13 MB)
3886 downloads. 2 comments
12.) Fog Outside

Welcome to the 12th OpenGL 3.3 tutorial! This time we'll discuss fog and how to program it using shaders. Fog is really nice and simple effect, which is often used in games not only to give a flavour to it, but also because it eliminates need of far clipping plane, because we won't see things far from us, because they are covered by fog anyway. So let's get started.

Fog

Fog is a collection of liquid water droplets or ice crystals suspended in the air at or near the Earth's surface. While fog is a type of stratus cloud, the term "fog" is typically... just Wikipedia definition. But I think there's no need to explain to anyone what is a fog, we all know that LULZ. We are going right to its implementation using shaders.

The basic idea behind fog should be something like that - the further object from camera is, the more covered in fog it should be. And we won't be calculating just how far objects are, but we'll do it for every single fragment in final image, because that's what modern GPU programming paradigms allows us. So the main idea is to calculate each fragment's distance from camera (it's reffered to as fogCoordinate, and then apply some function, which will calculate the fogFactor - how much fog to add to this fragment. Our fog will also have its color, so depending on fogFactor, we'll calculate final fragment color by mixing it with fog's color.

There are 3 basic functions, that calculate fog factor depending on fog coordinate. These are:

We'll go through each of these equations now.

Linear equation

There's not much to think of here. Simply fog factor should be linear interpolation between fog start and fog end, so the equation looks like this:

which can be easily written in GLSL as:
fogFactor = 1.0-clamp( (fogEnd-fogCoord)/(fogEnd-fogStart), 0.0, 1.0)
Graph will help you understand it even better:

Exp equation

This is my favourite equation, I think it gives nicest results. It takes one additional parameter - fog density. It should be a number ranging somewhere between 0.0 and 0.1, beyond these numbers fog is too dense or none (you can try to play with this value in application). It looks like this:

The distribution now isn't linear, but exponential, and as you can see in application, it seems a lot better than linear fog. The graph of this function looks like this (it's for density 0.04, but you should get an idea of how it looks):

There is a function exp in GLSL, that raises e to a specified power, so it's easy to write in GLSL:
fogFactor = 1.0-clamp( exp(-fogDensity*fogCoord), 0.0, 1.0)

Exp2 equation

The third and the last fog equation that is commonly used is exp2 equation. It looks like this:

Again, the power to 2 changes game a little. The density is even more sensible, so optimal range is somewhere between the 0.0 and 0.05, otherwise fog gets too intense (again, play with this value in demo so that you will see it). The graph of function looks like this (it's for density 0.03):

In GLSL, we can write with exp and pow functions (pow takes two parameters - number to raise, and number to raise to):
fogFactor = 1.0-clamp(exp(-pow(fogDensity*fogCoord, 2.0)), 0.0, 1.0)

Calculating fog coordinate

This is a key to success in order to program fog. But luckily, it's very easy. I would even say unbelievable easy LULZ. You just need to calculate eye space position of every vertex (we already know that), and then send it to fragment shader interpolated between every fragment to get eye space position of every fragment. We are interested in how deep or how far from us it is, so we are interested in z value. And since the eye space position is in homogeneous coordinates (we discussed it in 4th tutorial), we divide it with its w coordinate to obtain cartesian coordinates. And to top of all, we make an absolute value from it, because the result of these operations seems to be negative.

Here is a vertex shader for this:


#version 330

uniform struct Matrices
{
   mat4 projectionMatrix;
   mat4 modelViewMatrix;
   mat4 normalMatrix;
} matrices;

layout (location = 0) in vec3 inPosition;
layout (location = 1) in vec2 inCoord;
layout (location = 2) in vec3 inNormal;

smooth out vec2 texCoord;
smooth out vec3 vNormal;
smooth out vec4 vEyeSpacePos;

void main()
{
   vec4 vEyeSpacePosVertex = matrices.modelViewMatrix*vec4(inPosition, 1.0);
   gl_Position = matrices.projectionMatrix*vEyeSpacePosVertex;
   texCoord = inCoord;
   vec4 vRes = matrices.normalMatrix*vec4(inNormal, 0.0);
   vNormal = vRes.xyz;
   
   vEyeSpacePos = vEyeSpacePosVertex;   
}

I decided to structurize it a little, because these shader programs get more and more complex, and I don't want it to be a mess. Now almost every logical part of shader programs has at least its own struct. Not only that, if you remember how I have written in 3rd article about shaders, I said that shaders are like single source files, and we create a program and link them together. And that's what we'll use in this tutorial now. Fog will have it's own shader with fog factor calculation function in it, and main fragment shader will only have declaration of these functions and also struct declarations. Unluckily, GLSL doesn't have a support for something like #includefile preprocessor directive, so that we could define "header shader files" and "source shader files". Maybe you ask why not just #include. I read somewhere, that #include is a reserved keyword, I don't know if it's true, so I'd rather wouldn't use it. But it's not difficult to add some preprocessing into our loadShader function. We could add a case there, that if a line begins with word #includefile, we should paste the file there, and then compile it. I will probably do it in later tutorials, but I'm saying this now to give you an idea how linking multiple shader files works. It's good to isolate different shading algorithms into different shaders, and then just create shader programs consisting of their mixes. But for the purpose of this tutorial, we just copy & paste the struct and function declarations from fog shader. The fog shader looks like this:


#version 330

uniform struct FogParameters
{
   vec4 vFogColor; // Fog color
   float fStart; // This is only for linear fog
   float fEnd; // This is only for linear fog
   float fDensity; // For exp and exp2 equation
   
   int iEquation; // 0 = linear, 1 = exp, 2 = exp2
} fogParams;

float getFogFactor(FogParameters params, float fFogCoord)
{
   float fResult = 0.0;
   if(params.iEquation == 0)
      fResult = (params.fEnd-fFogCoord)/(params.fEnd-params.fStart);
   else if(params.iEquation == 1)
      fResult = exp(-params.fDensity*fFogCoord);
   else if(params.iEquation == 2)
      fResult = exp(-pow(params.fDensity*fFogCoord, 2.0));
      
   fResult = 1.0-clamp(fResult, 0.0, 1.0);
   
   return fResult;
}

As you can see, there is only struct containing fog parameters and fog factor calculatiion function. Now if we want to use this function in another shader file, we just need to declare it in it. And with it, also the struct must be declared in that shader file (that's why something like #includefile would be very useful). Of course, you can't forget to add this shader into shader program in initScene function. Now, let's have a look at fragment shader file with main function:


#version 330

smooth in vec2 texCoord;
smooth in vec3 vNormal;
smooth in vec4 vEyeSpacePos;
out vec4 outputColor;

uniform sampler2D gSampler;
uniform vec4 vColor;

uniform struct SimpleDirectionalLight
{
   vec3 vColor;
   vec3 vDirection;
   float fAmbientIntensity;
} sunLight;

uniform struct FogParameters
{
   vec4 vFogColor; // Fog color
   float fStart; // This is only for linear fog
   float fEnd; // This is only for linear fog
   float fDensity; // For exp and exp2 equation
   
   int iEquation; // 0 = linear, 1 = exp, 2 = exp2
} fogParams;

float getFogFactor(FogParameters params, float fFogCoord);

void main()
{
   vec4 vTexColor = texture2D(gSampler, texCoord);
   float fDiffuseIntensity = max(0.0, dot(normalize(vNormal), -sunLight.vDirection));
   outputColor = vTexColor*vColor*vec4(sunLight.vColor*(sunLight.fAmbientIntensity+fDiffuseIntensity), 1.0);
   
   // Add fog
   float fFogCoord = abs(vEyeSpacePos.z/vEyeSpacePos.w);
   outputColor = mix(outputColor, fogParams.vFogColor, getFogFactor(fogParams, fFogCoord));
}

In the end of it, we can see that we are calculating fog coordinate using the interpolated vEyeSpacePos, and then just mix colors depending on fog factor. GLSL function mix just adds two colors together, depending on third parameter factor like this: (1.0-factor)*color1 + factor*color2. One optimization that would save some processing time is not to interpolate whole eye space position, because we are not using x and y coordinates anyway, but rather directly calculate the fog factor in vertex shader, and send it interpolated into fragment shader. You can try it on your own, it should work as well.

In render scene function, fog parameters must be set before rendering. We do it as we always set uniforms:


#define FOG_EQUATION_LINEAR 0
#define FOG_EQUATION_EXP 1
#define FOG_EQUATION_EXP2 2

namespace FogParameters
{
   float fDensity = 0.04f;
   float fStart = 10.0f;
   float fEnd = 75.0f;
   glm::vec4 vFogColor = glm::vec4(0.7f, 0.7f, 0.7f, 1.0f);
   int iFogEquation = FOG_EQUATION_EXP; // 0 = linear, 1 = exp, 2 = exp2
};

void renderScene(LPVOID lpParam)
{
   // ...

   spFogAndLight.setUniform("fogParams.iEquation", FogParameters::iFogEquation);
   spFogAndLight.setUniform("fogParams.vFogColor", FogParameters::vFogColor);

   if(FogParameters::iFogEquation == FOG_EQUATION_LINEAR)
   {
      spFogAndLight.setUniform("fogParams.fStart", FogParameters::fStart);
      spFogAndLight.setUniform("fogParams.fEnd", FogParameters::fEnd);
   }
   else
      spFogAndLight.setUniform("fogParams.fDensity", FogParameters::fDensity);
   
   // ..
}

We just set these parameters, and we're ready to render a scene with fog. There is spiral made of box, it's coded in a minimalistic manner, but it shouldn't be a problem to understand how it works. If it is, let me know.

Result

Result seems to be very nice, see for yourself:

Don't forget to play around with keys 'F', '+', '-', PageUp and PageDown to change fog parameters and see the difference between different equations and their settings.

If you have problems with code compilation, don't forget to update libraries glm and FreeType to their latest versions. I'm trying to use latest versions in these tutorials.

Well, that's all for now, hope you liked it and the fog using shaders has been demystified for you LULZ. See you next time with lighting continued, we'll discuss point lights.



Download (2.13 MB)
3886 downloads. 2 comments
 
Name:

E-mail:
(Optional)
Entry:

Enter the text from image:



Smileys




Solomon (andradesolomon2011@gmail.com) on 03.08.2016 07:25:21
I would second the above comment: is the volumetric fog tutorial still in the plans? Thanks for the amazing site!
Anton (anton22255@ya.ru) on 07.05.2014 11:13:11
Hi! When can we see the next lesson with volumetric fog?
Jump to page:
1